The MsgBox Function and the MessageBox Class

 

The message box dialog is one of the most common ways to display custom messages to the user and accept their input regarding the choice that they have made. VB.NET provides two ways to use message boxes: the first is the MsgBox function, which is part of the Microsoft.VisualBasic namespace and is coded in a fashion very similar to pre-.NET versions of VB; the second is the MessageBox class, which has a slightly different syntax, and is the native .NET way to use message boxes. Both methodologies are presented below.

 

The MsgBox Function

 

The MsgBox function displays a message in a dialog box, waits for the user to click a button, and returns an Integer indicating which button the user clicked.

 

Syntax:

MsgBox(prompt[, buttons] [, title])

- or –

IntegerVariable = MsgBox(prompt[, buttons] [, title])

 

The MsgBox function syntax has these parts:

 

Part

Description

prompt

Required. String expression displayed as the message in the dialog box. The maximum length of prompt is approximately 1024 characters, depending on the width of the characters used.

buttons

Optional. Numeric expression that is the sum of values specifying the number and type of buttons to display, the icon style to use, the identity of the default button, and the modality of the message box. If omitted, the default value for buttons is 0 (which causes only an OK button to be displayed with no icon). The buttons argument is explained in more detail below.

title

Optional. String expression displayed in the title bar of the dialog box. If you omit title, the application name is placed in the title bar.

 

The buttons argument

 

The buttons argument is formed by five groups of values. The first group of values (0–5) describes the number and type of buttons displayed in the dialog box; the second group (16, 32, 48, 64) describes the icon style; the third group (0, 256, 512, 768) determines which button is the default; the fourth group (0, 4096) determines the modality of the message box; and the fifth group contains values that would only be used under special circumstances. When adding numbers to create a final value for the buttons argument, use only one number from each group.

 

Note: For each value, a corresponding built-in constant (either the classic "vb" constants or the .NET "MsgBoxStyle" enumeration constants) may also be used. Use of the constants is preferred for readability. The "vb" constants were introduced in earlier versions of Visual Basic and may also be used in VB.NET.  VB.NET also provides the "MsgBoxStyle" enumeration constants which can be used as an alternative to the "vb" constants.

 

First Group:

Determines which buttons to display:

 

Constant

Value

Description

vbOKOnly

- or -

MsgBoxStyle.OKOnly

0

Display OK button only.

vbOKCancel

- or -

MsgBoxStyle.OKCancel

1

Display OK and Cancel buttons.

vbAbortRetryIgnore

- or -

MsgBoxStyle.AbortRetryIgnore

2

Display Abort, Retry, and Ignore buttons.

vbYesNoCancel

- or -

MsgBoxStyle.YesNoCancel

3

Display Yes, No, and Cancel buttons.

vbYesNo

- or -

MsgBoxStyle.YesNo

4

Display Yes and No buttons.

vbRetryCancel

- or -

MsgBoxStyle.RetryCancel

5

Display Retry and Cancel buttons.

 

Second Group:

Determines which icon to display:

 

Constant

Value

Description

Icon

vbCritical

- or -

MsgBoxStyle.Critical

16

Display Critical Message icon.

vbQuestion

- or -

MsgBoxStyle.Question

32

Display Warning Query (question mark) icon.

vbExclamation

- or -

MsgBoxStyle.Exclamation

48

Display Warning Message icon.

vbInformation

- or -

MsgBoxStyle.Information

64

Display Information Message icon.

 

Third Group:

Determines which button is the default:

 

Constant

Value

Description

vbDefaultButton1

- or -

MsgBoxStyle.DefaultButton1

0

First button is default.

vbDefaultButton2

- or -

MsgBoxStyle.DefaultButton2

256

Second button is default.

vbDefaultButton3

- or -

MsgBoxStyle.DefaultButton3

512

Third button is default.

vbDefaultButton4

- or -

MsgBoxStyle.DefaultButton4

768

Fourth button is default (applicable only if a Help button has been added).

 

Fourth Group:

Determines the modality of the message box. Note – generally, you would not need to use a constant from this group, as you would want to use the default (application modal). If you specified "system modal", you would be "hogging" Windows – i.e., if a user had another app open, like Word or Excel, they would not be able to get back to it until they responded to your app's message box.

 

Constant

Value

Description

vbApplicationModal

- or -

MsgBoxStyle.ApplicationModal

0

Application modal; the user must respond to the message box before continuing work in the current application.

vbSystemModal

- or -

MsgBoxStyle.SystemModal

4096

System modal; all applications are suspended until the user responds to the message box.

 

Fourth Group:

The fifth group of constants that can be used for the buttons argument would only be used under special circumstances:

 

Constant

Value

Description

vbMsgBoxHelpButton

- or -

MsgBoxStyle.MsgBoxHelpButton

16384

Adds Help button to the message box

vbMsgBoxSetForeground

- or -

MsgBoxStyle.MsgBoxSetForeground

65536

Specifies the message box window as the foreground window

vbMsgBoxRight

- or -

MsgBoxStyle.MsgBoxRight

524288

Text is right aligned

vbMsgBoxRtlReading

- or -

MsgBoxStyle.MsgBoxRtlReading

1048576

Specifies text should appear as right-to-left reading on Hebrew and Arabic systems

 

When you use MsgBox to with the option to display more than one button (i.e., from the first group, anything other than "vbOKOnly"), you can test which button the user clicked by comparing the return value of the Msgbox function with one of these values.

 

Note: For each return value, a corresponding built-in constant (either the classic "vb" constants or the .NET "MsgBoxResult" enumeration constants) may also be used. Use of the constants is preferred for readability. The "vb" constants were introduced in earlier versions of Visual Basic and may also be used in VB.NET.  VB.NET also provides the "MsgBoxResult" enumeration constants which can be used as an alternative to the "vb" constants.

 

Constant

Value

Description

vbOK

-or-

MsgBoxResult.OK

1

The OK button was pressed

vbCancel

-or-

MsgBoxResult.Cancel

2

The Cancel button was pressed

vbAbort

-or-

MsgBoxResult.Abort

3

The Abort button was pressed

vbRetry

-or-

MsgBoxResult.Retry

4

The Retry button was pressed

vbIgnore

-or-

MsgBoxResult.Ignore

5

The Ignore button was pressed

vbYes

-or-

MsgBoxResult.Yes

6

The Yes button was pressed

vbNo

-or-

MsgBoxResult.No

7

The No button was pressed

           

Note:    To try any of the MsgBox examples, you can simply start a new project, double-click on the form, and place the code in the Form_Load event.

 

There are two basic ways to use MsgBox, depending on whether or not you need to know which button the user clicked.

 

·         If you do NOT need to test which button the user clicked (i.e., you displayed a message box with only an OK button), then you can use MsgBox as if you were calling a Sub. You can use the following syntax:

 

MsgBox(arguments)

 

            Examples:

 

o    The statement

 

MsgBox("Hello there!")

                       

causes the following box to be displayed:

 

                                                             

 

                        This is the simplest use of MsgBox: it uses only the required prompt argument. Since the buttons argument was omitted, the default (OK button with no icons) was used; and since the title argument was omitted, the default title (the project name) was displayed in the title bar.

 

o    The statement

 

MsgBox("The Last Name field must not be blank.", _

       vbExclamation, _

       "Last Name")

                       

causes the following box to be displayed:

 

 

                        This is how a data entry error might be displayed. Note that vbExclamation was specified for the buttons argument to specify what icon should be displayed – the fact that we did not add a value from the first group still causes only the OK button to be displayed. If you wanted to explicitly indicate that only the OK button should be displayed along with the exclamation icon, you could have coded the second argument as

 

vbExclamation + vbOKOnly

                       

making the full statement read:

 

MsgBox("The Last Name field must not be blank.", _

       vbExclamation + vbOKOnly, _

       "Last Name")

 

            Remember, for the buttons argument, you can add one value from each of the four groups.

 

                        An alternative (not recommended) is to use the hard-coded number for the buttons argument, as in:

 

MsgBox("The Last Name field must not be blank.", 48, "Last Name")

 

                        Note also that this example provided a value for the title argument ("Last Name"), which causes that text to be displayed in the box's title bar.

 

The format of the MsgBox statement used in this example could also be used for more critical errors (such as a database problem) by using the vbCritical  icon. You may also want to use the name of the Sub or Function in which the error occurred for your title argument.

 

Example:

 

MsgBox("A bad database error has occurred.", _

       vbCritical, _

       "UpdateCustomerTable")

 

Result:

 

 

·         If you DO need to test which button the user clicked (i.e., you displayed a message box with more than one button), then you must use MsgBox as a function, using the following syntax:

 

IntegerVariable = Msgbox (arguments)

 

            One of the more common uses of MsgBox is to ask a Yes/No question of the user and perform processing based on their response, as in the following example:

 

Dim intResponse As Integer

 

intResponse = MsgBox("Are you sure you want to quit?", _

                     vbYesNo + vbQuestion, _

                     "Quit")

 

If intResponse = vbYes Then

    ' code to end the app, such as "Me.Close" would go here

End If   

 

The following message box would be displayed:

 

 

            After the user clicks a button, you would test the return variable (intResponse) for a value of vbYes or vbNo (6 or 7).

 

Note that the use of the built-in constants makes the code more readable. The statement

 

intResponse = MsgBox("Are you sure you want to quit?", _

                     vbYesNo + vbQuestion, _

                     "Quit")

is more readable than

 

intResponse = MsgBox("Are you sure you want to quit?", 36, "Quit")

and

 

If intResponse = vbYes Then

 

is more readable than

 

If intResponse = 6 Then

 

 

            In that you can use a function anywhere a variable can be used, you could use the MsgBox function directly in an If statement without using a separate variable to hold the result ("intResponse" in this case). For example, the above example could have been coded as:

 

If MsgBox("Are you sure you want to quit?", _

          vbYesNo + vbQuestion, _

          "Quit")= vbYes Then

    ' code to end the app, such as "Me.Close" would go here

End If   

 

 

Note: If desired you could place the code for this example in the cmdExit_Click event of any of the "Try It" projects.

 

Following is an example using the vbDefaultButton2 constant:

 

Dim intResponse As Integer

 

intResponse = MsgBox("Are you sure you want to delete all of the rows " _

                   & "in the Customer table?", _

                     vbYesNo + vbQuestion + vbDefaultButton2, _

                     "Delete")

 

If intResponse = vbYes Then

    ' code to delete the rows would go here ...

End If   

 

The message box displayed by this example would look like this:

 

 

           

 

The first sample project for this topic contains a command button for each MsgBox example given above.

 

 

Download the VB.NET project code for the example above here.

 

The MessageBox Class

 

As an alternative, .NET has introduced a class called MessageBox which encapsulates all the features of MsgBox. The difference between MsgBox and MessageBox is that Msgbox is a function while MessageBox is a class. The MessageBox class has various overloaded Show methods for different parameters. From a practical standpoint, both the MsgBox function and the MessageBox class will accomplish the same thing. You will notice that the arguments for MessageBox are specified in a slightly different order from MsgBox.

 

MessageBox.Show Method

 

To show the message box we need to call the Show method of the MessageBox class, for example:

 

MessageBox.Show("Hello World!")

 

As mentioned earlier, the Show method has various overloaded forms. From a practical standpoint, the syntax usage of the MessageBox.Show method can be looked as follows:

 

[DialogResult = ] MessageBox.Show([window ,]

                                   prompt

                                  [, caption]

                                  [, MessageBoxButtons]

                                  [, MessageBoxIcon]

                                  [, MessageBoxDefaultButton]

                                  [, MessageBoxOptions])    

 

An explanation of the Show method arguments is shown in the list below:

 

window

The window that the message box will display in front of (for example, you could specify "Me" to refer to the current form). This argument is typically omitted.

prompt

The text to display in the message box. This is the only required argument

caption

The text to display in the title bar of the message box. If omitted, the project name will be displayed.

MessageBoxButtons

Specifies which buttons to display on the message box. Possible values are:

  • MessageBoxButtons.AbortRetryIgnore (displays the Abort, Retry, and Ignore buttons)
  • MessageBoxButtons.OK (displays the OK button)
  • MessageBoxButtons.OKCancel (displays the OK and Cancel buttons)
  • MessageBoxButtons.RetryCancel (displays the Retry and Cancel buttons)
  • MessageBoxButtons.YesNo (displays the Yes and No buttons)
  • MessageBoxButtons.YesNoCancel (displays the Yes, No, and Cancel buttons)

MessageBoxIcon

Specifies which icon to display on the message box. Possible values are:

Value

Icon

MessageBoxIcon.Error

- or -

MessageBoxIcon.Hand

- or -

MessageBoxIcon.Stop

 

MessageBoxIcon.Question

 

MessageBoxIcon.Exclamation

- or -

MessageBoxIcon.Warning

 

MessageBoxIcon.Asterisk

- or -

MessageBoxIcon.Information

 

MessageBoxIcon.None

 

(none)

MessageBoxDefaultButton

Specifies the default button for the message box. Possible values are:

·         MessageBoxDefaultButton.Button1 (the first message box button is the default button)

·         MessageBoxDefaultButton.Button2 (the second message box button is the default button)

·         MessageBoxDefaultButton.Button3 (the third message box button is the default button)

MessageBoxOptions

Allows specialized options to be specified. Possible values are:

·         MessageBoxOptions.DefaultDesktopOnly (displays the message box on the active desktop)

·         MessageBoxOptions.RightAlign (displays the message box text right-aligned)

·         MessageBoxOptions.RtlReading (displays the text in right-to-left reading order)

·         MessageBoxOptions.ServiceNotification (displays the message box on the active desktop, even if there is no user logged on to the computer)

 

Return values from MessageBox are returned in a DialogResult (Integer) datatype. Possible values for DialogResult are:

 

Value

Description

DialogResult.OK

The OK button was pressed

DialogResult.Cancel

The Cancel button was pressed

DialogResult.Abort

The Abort button was pressed

DialogResult.Retry

The Retry button was pressed

DialogResult.Ignore

The Ignore button was pressed

DialogResult.Yes

The Yes button was pressed

DialogResult.No

The No button was pressed

DialogResult.None

Nothing is returned from the dialog box. This means that the modal dialog continues running.

           

Sample MessageBox statements along with their corresponding display are shown below:

 

Statement

Display

MessageBox.Show("Hello there!")

 

MessageBox.Show _

    ("The Last Name field must not be blank.",  _

     "Last name", _

     MessageBoxButtons.OK, _

     MessageBoxIcon.Exclamation)

 

 

MessageBox.Show _

    ("A bad database error has occurred.", _

     "UpdateCustomerTable", _

     MessageBoxButtons.OK, _

     MessageBoxIcon.Error)

 

 

Dim intResponse As DialogResult

 

intResponse = MessageBox.Show _

                ("Are you sure you want to quit?", _

                 "Quit", _

                 MessageBoxButtons.YesNo, _

                 MessageBoxIcon.Question)

 

If intResponse = DialogResult.Yes Then

    ' end the program

End If

 

Dim intResponse As DialogResult

 

intResponse = MessageBox.Show _

               ("Are you sure you want to " & _

                "delete all of the rows " & _

                "in the Customer table?", _

                "Delete", _

                MessageBoxButtons.YesNo, _

                MessageBoxIcon.Question, _

                MessageBoxDefaultButton.Button2)

 

If intResponse = DialogResult.Yes Then

    ' delete the rows ...

End If

 

 

The second sample project for this topic contains a command button for each MessageBox example given above.

 

 

Download the VB.NET project code for the example above here.